Project

General

Profile

Full-Pallette Random Nick Color Script fork v0.1.7.ini

Mr. BS, 05/20/2016 06:38 PM

 
1
; https://dev.adiirc.com/boards/5/topics/308
2

    
3
; Hackjob full-palette Random Nick Color script for AdiIRC
4
; Generate consistent but random, full-palette colors for nicks & set custom colors as you please
5
;
6
; Version 1.2 - Fork v0.1.7 by Pereba
7
;
8
;
9
; *Now allows storage of custom colors!
10
;		Usage: /setCustomColor <Nick> <Hex Color Code> - Example: /setCustomColor JohnDoe F854A7
11
;				/delCustomColor <Nick> - Example: /delCustomColor JohnDoe
12
;
13
; *Colors are now calculated once and stored as needed for both random and custom colors
14
;	This decreases CPU time (especially on bouncer playback) for each line displayed
15
; 	Custom colors persist between sessions (stored as rcolorscustom in your AdiIRC folder)
16
;
17
; *Buffer playback from bouncers is now properly supported without mangling output
18
;
19
; **NOTE: The built-in "Use Random Nick Colors" (Options -> Nick Colors) must be disabled for this script to work 
20
; **NOTE: Any nick colors set in the AdiIRC options menu override random or custom colors set by this script
21
;
22
; Thanks to pereba for the original inspiration script and kr0n for troubleshooting help, as well as 
23
; introducing me to hashtables :)
24
;
25
; For any of the output strings, if you don't want to show usermodes, you can replace $nick($chan, $nick).pnick
26
;  with just plain $nick
27
;
28
; If you're curious, $chr(61442) is a special AdiIRC character that interprets the following string as a hex 
29
; color code and allows for colorizing text
30
;
31
; If the script is acting weird for you, consider updating to the latest release or beta of AdiIRC; 
32
; some of this code relies on features or bufixes in later versions
33
;
34
; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
35
;
36
; This is the initialization section, it handles actions to take when the script is loaded for 
37
; the first time or reloaded, 
38
;
39
;
40
; whenever the script is loaded for the first time or reloaded, call /savereload, 
41
; which saves the rcolors and rcolorscustom hashtables to disk, clears them from memory, 
42
; then reloads them--this also handles reloading them from disk when AdiIRC first starts
43
;
44
on *:LOAD:savereload
45
on *:START:{
46
  hadd -m rcolors 0bgcolor $color(34)
47
  savereload
48
}
49
;
50
; save & overwrite the rcolors & rcolorscustom hashtables to disk on exit
51
;
52
on *:Exit:{
53
hsave -o rcolors rcolors
54
hsave -o rcolorscustom rcolorscustom
55
}
56
; dump all cached colors when the options screen is loaded; this ensures no stale colors are used
57
; if the background color is changed, since they might not be easy enough to see
58
on *:OPTIONS:{
59
  if ($hget(rcolors,0bgcolor) != $color(34)) {
60
    reset
61
  }
62
  if ($readini($adiircini,n,NickColors,NickColorsEntireLine) == True) {
63
    set -e %rcolors_ColorEntireLine True
64
  }
65
  else {
66
    unset %rcolors_ColorEntireLine
67
  }
68
}
69

    
70
;
71
; This section responds to normal in-channel text events
72
;
73
on &^*:TEXT:*:#:{
74
;
75
; Stop here if user turned off script
76
;
77
if (%rcolors_disabled) return
78
;
79
; Disable script on blacklisted networks/channels
80
;
81
if ($network $+ . $+ # isin %rcolors_blacklist) return
82
;
83
; Check if message is ZNC buffer playback and use values accordingly
84
; ZNC buffer playback has different message content than a normal message and needs different handling
85
;
86
  var %time $spacefix($asctime($iif($msgstamp, $v1, $ctime), $timestampfmt))
87
  var %pnick $iif($nick(#,$nick).cnick, $v1, $nick)
88
  ;;$nick($chan, $nick).pnick
89
; build the echo string
90
  ;;;echo -vrlmbfw2 # %time $replace($replace($prefixuser, $chr(32), $chr(160)), $ $+ pnick, $+($chr(61442), $getcolor, %pnick, $chr(3)))  $1-
91
  
92
  var %linecolor $chr(3) $+ $chr(61442) $+ $getcolor
93
  var %prefixuser $replace($prefixuser,$!pnick,%pnick,$chr(32),$chr(160))
94
  var %msg $msgx
95
  ; check if message triggered a highlight to use respective color in echo
96
  var %h $highlight($iif($1- !isnum,$v1))
97

    
98
  ; Color entire prefixuser or just the nick? follow user preference:
99
  if (%rcolors_ColorEntirePrefixUser) {
100
    var %prefixuser %linecolor $+ $replace($prefixuser,$!pnick,%pnick,$chr(32),$chr(160)) $+ $chr(3)
101
  }
102
  else {
103
    var %prefixuser $replace($prefixuser,$!pnick,%linecolor $+ %pnick $+ $chr(3),$!nick,%linecolor $+ %pnick $+ $chr(3),$chr(32),$chr(160))
104
  }
105

    
106
  ; If Options -> Nick Colors -> Color entire line is enabled:
107
  if (%rcolors_ColorEntireLine && !%h) {
108
    %prefixuser = %prefixuser $+ %linecolor
109
    %msg = $regsubex(%msg,$patLine,%linecolor)
110
    if (%rcolors_ColorTimestamp) { %time = %linecolor $+ $regsubex(%time,$patLine,%linecolor) $+ $chr(3) }
111
  }
112
    
113
  %msg = %time %prefixuser %msg
114
  echox -vrlmbfw2 # %msg
115
  halt
116
}
117
;
118
; This section handles ACTIONs, like /me or /emote commands
119
; Mostly the same as PRIVMSG but with the output string adjusted to properly display these types of messages
120
;
121
on &^*:ACTION:*:#:{
122
  ;
123
  ; Stop here if user turned off script
124
  ;
125
  if (%rcolors_disabled) return
126
  var %time $spacefix($asctime($iif($msgstamp, $v1, $ctime), $timestampfmt))
127
  var %pnick $iif($nick(#,$nick).cnick, $v1, $nick)
128
  var %linecolor $chr(3) $+ $chr(61442) $+ $getcolor
129
  var %msg $msgx
130
  ; check if message triggered a highlight to use respective color in echo
131
  var %h $highlight($iif($1- !isnum,$v1))
132
  
133
  ; Color just the nick or entire prefixuser? follow user preference:
134
  var %prefixbase $replace($prefixemote,$!pnick,%linecolor $+ %pnick $+ $chr(3),$!nick,%linecolor $+ %pnick $+ $chr(3),$chr(32),$chr(160)), %prefixuser %prefixbase
135
  if (%rcolors_ColorEntirePrefixUser) {
136
    %prefixuser = %linecolor $+ $replace($prefixemote,$!pnick,%pnick,$chr(32),$chr(160)) $+ $chr(3)
137

    
138
    ; Color only pnick if Color Entire Line is diabled for emotes
139
    if (!%rcolors_ColorEntireLine || !%rcolors_ColorEmote) {
140
      %prefixuser = %prefixbase
141
    }
142
  }
143

    
144
  ; If Options -> Nick Colors -> Color entire line is enabled:
145
  if (%rcolors_ColorEntireLine && !%h) {
146
    %prefixuser = %prefixuser $+ %linecolor
147
    %msg = $regsubex(%msg,$patLine,%linecolor)
148
    if (%rcolors_ColorTimestamp) { %time = %linecolor $+ $regsubex(%time,$patLine,%linecolor) $+ $chr(3) }
149
  }
150
  
151
  var %msgx %time %prefixuser $+ $iif(!%rcolors_ColorEmote,$chr(3)) %msg
152
 
153
  ;build the echo string
154
  echox -vrlmbfw2c action # %msgx
155
  halt 
156
}
157

    
158
;alias me echo -ag memememeem
159
;alias action echo -ag action baby
160

    
161
;
162
; User own text
163
;
164
on *:INPUT:#: {
165
  ;
166
  ; Stop here if user turned off script
167
  ;
168
  if (%rcolors_disabled) return
169
  
170
  noop $regex(e,$1,/^(?:(\/{1,4})(me|action)?\b)?/i)  
171
  if ( ($regml(e,0) != 1) || ($ctrlenter) ) && ($status == connected) {
172
    var %time $spacefix($asctime($iif($msgstamp, $v1, $ctime), $timestampfmt))
173
    var %pnick $iif($nick(#,$nick).cnick, $v1, $nick)
174
    var %linecolor $chr(3) $+ $chr(61442) $+ $getcolor
175
    var %msgxraw $replacex($iif($regml(e,1), $iif($len($v1) > 1,$($mid($msgx,$calc($len($1) +2)),2),$mid($msgx,$calc($len($1) +2))), $msgx),$chr(9),$chr(160))
176
    var %msg %msgxraw
177
    
178
    ; Color just the nick or entire prefixuser? follow user preference:
179
    var %prefixbase $replace($iif($regml(e,2),$prefixemote,$prefixuser),$!pnick,%linecolor $+ %pnick $+ $chr(3),$!nick,%linecolor $+ %pnick $+ $chr(3),$chr(32),$chr(160)), %prefixuser %prefixbase
180
    if (%rcolors_ColorEntirePrefixUser) {
181
      %prefixuser = %linecolor $+ $replace($iif($regml(e,2),$prefixemote,$prefixuser),$!pnick,%pnick,$chr(32),$chr(160)) $+ $chr(3)
182
      
183
      ; Color only pnick if Color Entire Line is diabled for emotes
184
      if (($regml(e,2)) && (!%rcolors_ColorEntireLine || !%rcolors_ColorEmote)) {
185
        %prefixuser = %prefixbase
186
      }
187
    }
188

    
189
    ; If Options -> Nick Colors -> Color entire line is enabled: (except /action msg)
190
    if (%rcolors_ColorEntireLine) {
191
      if ($regml(e,2) && !%rcolors_ColorEmote) {
192
      }
193
      else {
194
        %prefixuser = $iif(%rcolors_ColorEmote,%linecolor) $+ %prefixuser $+ %linecolor
195
        %msg = $regsubex(new,%msgxraw,$patLine,%linecolor)
196
        if (%rcolors_ColorTimestamp) { %time = %linecolor $+ $regsubex(t,%time,$patLine,%linecolor) $+ $chr(3) }
197
      }
198
    }
199

    
200
    ; Action VS regular message
201
    if ($regml(e,2)) {
202
      var %msgx %time %prefixuser $+ $iif(!%rcolors_ColorEmote,$chr(3)) %msg, %text PRIVMSG $active : $+ $chr(1) $+ ACTION %msgxraw $+ $chr(1)
203
      echox -vw2c action # %msgx
204
    }
205
    else {
206
      var %msgx %time %prefixuser %msg, %text PRIVMSG $active : $+ %msgxraw
207
      echox -vw2c own # %msgx
208
    }
209
    .rawx %text
210
    halt
211
  }
212
}
213

    
214
;
215
; Coloring nicklist
216
;
217
on me:*:join:#:{
218
  ; If enabled continue
219
  if (%rcolors_nicklist) {
220
    .timer 1 3 clinergb #
221
  }
222
}
223

    
224
on *:JOIN:#:{
225
  ; If enabled continue
226
  if (%rcolors_nicklist) {
227
    cline -b $rgb( [ $hex2rgb($iif(%rcolors_nicklistbg == 1, $getDarkColor($nick), $getBrightColor($nick))) ] ) $nick
228
  }
229
}
230
; credits @ http://forums.mirc.com/ubbthreads.php/topics/153480/HEX_=%3E_RGB?
231
alias hex2rgb {
232
  $iif($isid,return,echo -a) $+($base($left($1,2),16,10),$chr(44),$base($mid($1,3,2),16,10),$chr(44),$base($right($1,2),16,10))
233
}
234

    
235
alias -l clinergb {
236
  if ($istok(%rcolors_blacklist,$network $+ . $+ $1,32)) {
237
    var %rcolors_disabled 1
238
  }
239
  var %n $nick($1,0)
240
  while (%n) {
241
    cline $iif(%rcolors_nicklist && %rcolors_disabled != 1,-b $rgb( [ $hex2rgb($iif(%rcolors_nicklistbg == 1, $getDarkColor($nick($1,%n)), $getBrightColor($nick($1,%n)))) ] ), -r) $1 $nick($1,%n)
242
    dec %n
243
  }
244
}
245

    
246
alias -l resetNicklist {
247
  tokenize 32 $regsubex($str(x,$chan(0)),/x/g,\n $chr(32))
248
  clinergb $chan($*)
249
}
250

    
251
; credits Kin @ GeekShed
252
alias -l patLine return /\co|(\cc(?!\d(?:\d(?:,\d\d?)?)?))/gu
253

    
254
alias -l spacefix {
255
  return $replacex($1,$chr(32),$chr(160))
256
}
257

    
258
alias -l getcolor {
259
; Initialize %color as neutral grey in case we end up with nothing else to return
260
  var %color = 888888
261
; Check if nick has a custom color set in AdiIRC options; if it does, return that color
262
  if ($nick(#, $nick).color > 1) {
263
    var %color = $getHexOfColor($nick(#, $nick).color))
264
    return %color
265
}
266
; Check if nick has a script-custom color; if it does, return that color
267
  else if ($hget(rcolorscustom, $nick)) {
268
    var %color = $hget(rcolorscustom, $nick)
269
    return %color
270
    }
271
; Check if nick has a cached color, if it does, return that color
272
  else if ($hget(rcolors, $nick)) {
273
    var %color = $hget(rcolors, $nick)
274
    return %color
275
  }
276
; If no cached or custom colors are found, roll for a new color and add it to the cache
277
  else {
278
    var %color $iif(%rcolors_bg == 1, $getDarkColor, $getBrightColor)
279
    hadd -m rcolors $nick %color
280
    return %color
281
  }
282
; If something fails, return %color as originally set to 888888
283
  return %color
284
}
285

    
286
;
287
;
288
;
289
; This is the alias for generating bright colors
290
;
291
alias -l getBrightColor {
292
;
293
; Generate a unique seed number by calculating the MD5 hash of a nick, interpreting the last 8 characters as a hex number, then converting that to decimal
294
;
295
  ;;;var %nickSeedNum = $base($right($md5($nick),8),16,10)
296
  var %nickSeedNum = $base($right($md5($iif($1,$1,$nick)),8),16,10)
297
;
298
; Multiply by a high prime number, then take the modulus of a prime number < 255 to get 3 values for R,G,B color; this induces a bit more variety in the colors, and
299
; for whatever reason (I'm not a mathematician) tends to "favor" returning numbers close to 255 (brighter colors)
300
;
301
  var %dec1 = $calc((%nickSeedNum * 7793) % 251)
302
  var %dec2 = $calc((%nickSeedNum * 5153)  % 241)
303
  var %dec3 = $calc((%nickSeedNum * 3623) % 239)
304
;
305
; Take the average of the RGB values 
306
;
307
  var %decaverage = $calc((%dec1 + %dec2 + %dec3)/3)
308
;
309
; Generate colors until you get one that is "bright" (average RGB value > 128)
310
; If you find these colors are too dark or bright, you can adjust the %decaverage <= 128
311
;
312
  while (%decaverage <= 128) {
313
    var %dec1 = $calc((%dec1 * 7793) % 251)
314
    var %dec2 = $calc((%dec2 * 5153) % 241)
315
    var %dec3 = $calc((%dec3 * 3623) % 239)
316
    var %decaverage = $calc((%dec1 + %dec2 + %dec3)/3)
317
  }
318
;
319
; call $RGBToHex to turn the RGB Value into a hex color code and return that code
320
;
321
  var %brightColorReturn = $RGBToHex(%dec1,%dec2,%dec3)
322
  return %brightColorReturn
323
}
324
;
325
; This is the alias for generating dark colors
326
; It's the same as $getBrightColor but looks for colors that are "dark", or have
327
; average RGB value < 128 - Again you can tweak the %decaverage <= 128 if they're too dark or bright
328
;
329
alias -l getDarkColor {
330
  ;var %nickSeedNum = $base($right($md5($nick),8),16,10)
331
  var %nickSeedNum = $base($right($md5($iif($1,$1,$nick)),8),16,10)
332
  var %dec1 = $calc((%nickSeedNum * 7793) % 113)
333
  var %dec2 = $calc((%nickSeedNum * 5153) % 127)
334
  var %dec3 = $calc((%nickSeedNum * 3623) % 131)
335
  var %decaverage = $calc((%dec1 + %dec2 + %dec3)/3)
336

    
337
  while (%decaverage >= 128) {
338
    var %dec1 = $calc((%dec1 * 7793) % 113)
339
    var %dec2 = $calc((%dec2 * 5153) % 127)
340
    var %dec3 = $calc((%dec3 * 3623) % 131)
341
    var %decaverage = $calc((%dec1 + %dec2 + %dec3)/3)
342
  }
343
  var %darkColorReturn = $RGBToHex(%dec1,%dec2,%dec3)
344
  return %darkColorReturn
345
}
346
;
347
; This is the alias for converting RGB values to Hex, used here for getting hex strings to put 
348
; after $chr(61442) - see top if you're not sure what this character is
349
;
350
; it takes in 3 numbers from 0-255, converts them to hex numbers, 
351
; then returns them as a single string, EG $RGBToHex(255,255,255) or "White" returns FFFFFF
352
;
353
alias -l RGBToHex {
354
  var %RtoHex = $base($1,10,16,2)
355
  var %GtoHex = $base($2,10,16,2)
356
  var %BtoHex = $base($3,10,16,2)
357
  var %HexCodeReturn = %RToHex $+ %GToHex $+ %BToHex
358
  return %HexCodeReturn
359
}
360
;
361
; This is the alias for determining if your background is bright
362
;
363
; Average RGB of 100 seems to work well for determining if background is light or dark,
364
; but if you find the script is using colors that aren't showing well you might want to 
365
; adjust this
366
;
367
alias -l isBackgroundBright {
368
;
369
; get the backgound color
370
;
371
  var %bgRGB = $rgb($iif($1,$color(27),$color(34)))
372
;
373
; strip out the commas and replace them with the + sign
374
;
375
  var %bgRGB = $replace(%bgRGB,$chr(44),$chr(43))
376
;
377
; evaluate the string from above
378
;
379
  var %bgRGBAverage = $calc((%bgRGB)/3)
380
;
381
; check if the average RGB value of the background is > 100; 
382
; return 1 if it is (bright) or 0 if it isn't (dark)
383
;
384
  if (%bgRGBAverage >= 100) { 
385
    return 1
386
  }
387
  else return 0
388
}
389

    
390
;
391
; This is the alias that gets the hex value of numbered config colors 
392
; https://dev.adiirc.com/projects/adiirc/wiki/Extra_Colors
393
;
394
; It is used in this script only to keep nicks with custom colors set using 
395
; those colors instead of picking random colors
396
;
397
alias -l getHexOfColor {
398
;
399
; get the specified color's R,G,B value
400
  var %colorToGet = $rgb($color($1))
401
;
402
; tokenize the string returned above with commas ($chr(44)) as delimiter; pass those values into the $RGBToHex alias and return the value
403
  tokenize 44 %colorToGet
404
  return $RGBToHex($1,$2,$3)
405
}
406
;
407
; This is the alias for setting custom nick colors, it takes a Nick and a hex color code as arguments
408
; EXAMPLE /setCustomColor JohnDoe f854a7
409
;
410
alias setCustomColor {
411
; typing just /setcustomcolor returns rudimentary help
412
; otherwise write the nick+color to hash table rcolorscustom and save to disk
413
   $iif($1, /echo -at $+($chr(61442),$2) Set this color for nick $1, /echo -at Usage: /setCustomColor <Nick> <Hex Color Code> Example: /setCustomColor JohnDoe F854A7)
414
   
415
   hadd -m rcolorscustom $1 $2
416
   hsave -o rcolorscustom rcolorscustom
417
}
418
;
419
; This is the alias for deleting custom nick colors, it takes only a nick as an argument
420
; EXAMPLE /delCustomColor JohnDoe
421
alias delCustomColor {
422
; typing just /delcustomcolor returns rudimentary help
423
; otherwise remove nick+color from hash table rcolorscustom and save to disk
424
   $iif($1, echo -at Trying to remove custom color for $1, /echo -at Usage: /delCustomColor  <Nick> Example: /delCustomColor JohnDoe)
425
   hdel rcolorscustom $1
426
   hsave -o rcolorscustom rcolorscustom
427
}
428
;
429
; This is the alias for clearing all cached random colors
430
; It empties the rcolors hashtable, then saves the empty table back to the disk
431
; It is generally used in this script for ensuring that colors adjust accordingly to background color changes
432
;
433
alias -l reset {
434
; Remove all cached colors
435
  if ($hget(rcolors)) {
436
    .hdel -w rcolors *
437
	savereload
438
  }  
439
; Check if background is light or dark and set %rcolors_bg accordingly
440
  ;;;set %rcolors_bg $isBackgroundBright
441
  set %rcolors_bg $iif($var(%rcolors_forcestyle,1).value != $null,$v1,$isBackgroundBright)
442
  rcolors_resetnicklist
443
}
444
alias -l rcolors_resetnicklist {
445
  set %rcolors_nicklistbg $iif($var(%rcolors_nickliststyle,1).value != $null,$v1,$isBackgroundBright(nicklist))
446
}
447
;
448
; This is the alias for saving & reloading cached & custom colors to disk. It is primarily used on first run, or when
449
; settings are changed and need to be stored
450
; 
451

    
452
alias savereload {
453
; check if the rcolors hashtable exists, if it does, save it to disk, purge all entries from memory and reload it.
454
; it also checks if the hashtable is too large (more than 1000 entries) and purges it if that's the case
455
; if the hashtable is purged, colors will be recalculated and entered the next time a person speaks
456
	if ($hget(rcolors)) {
457
		if ($hget(rcolors,0).item > 1000) {
458
			.hdel -w rcolors *
459
		}
460
		hsave -o rcolors rcolors
461
		.hdel -w rcolors *
462
		hload rcolors rcolors
463
	}
464
    else { 
465
		hmake rcolors 100
466
	}
467
; same as above, but with rcolorscustom
468
; rcolorscustom will also never be auto-cleared  
469
   if ($hget(rcolorscustom)) {
470
	hsave -o rcolorscustom rcolorscustom
471
	.hdel -w rcolorscustom *
472
	hload rcolorscustom rcolorscustom
473
	}
474
            else { 
475
            hmake rcolorscustom 100
476
            }
477
                      
478
}
479

    
480
menu channel {
481
  RGB Random Nick Colors
482
  .Disable in #
483
  ..$iif($network $+ . $+ # isin %rcolors_blacklist,$style(1)) Yes:set %rcolors_blacklist $addtok(%rcolors_blacklist,$network $+ . $+ #,32) | clinergb #
484
  ..$iif($network $+ . $+ # !isin %rcolors_blacklist,$style(1)) No:set %rcolors_blacklist $deltok(%rcolors_blacklist,1,$network $+ . $+ #) | clinergb #
485
}
486

    
487
menu menubar {
488
  RGB Random Nick Colors
489
  .$iif(!%rcolors_disabled,$style(1)) Enabled:$iif(%rcolors_disabled,unset %rcolors_disabled,set %rcolors_disabled 1) | $iif(%rcolors_nicklist,scid -a resetNicklist)
490
  .-
491
  .Color messages style
492
  ..$iif(%rcolors_forcestyle == $null,$style(1)) Auto:unset %rcolors_forcestyle | reset
493
  ..$iif(%rcolors_forcestyle == 0,$style(1)) Bright:set %rcolors_forcestyle 0 | reset
494
  ..$iif(%rcolors_forcestyle == 1,$style(1)) Dark:set %rcolors_forcestyle 1 | reset
495
  .Color entire prefix user
496
  ..$iif(%rcolors_ColorEntirePrefixUser,$style(1)) Yes:set %rcolors_ColorEntirePrefixUser True
497
  ..$iif(%rcolors_ColorEntirePrefixUser != True,$style(1)) No:unset %rcolors_ColorEntirePrefixUser
498
  .Color entire message
499
  ..$iif(%rcolors_ColorEntireLine,$style(1)) Yes:.setconfig NickColors NickColorsEntireLine True | set %rcolors_ColorEntireLine True
500
  ..$iif(%rcolors_ColorEntireLine != True,$style(1)) No:.setconfig NickColors NickColorsEntireLine False | unset %rcolors_ColorEntireLine False
501
  .└ Including emote message
502
  ..$iif(%rcolors_ColorEmote,$style(1)) Yes:set %rcolors_ColorEmote True
503
  ..$iif(%rcolors_ColorEmote != True,$style(1)) No:unset %rcolors_ColorEmote
504
  .└ Including timestamp
505
  ..$iif(%rcolors_ColorTimestamp,$style(1)) Yes:set %rcolors_ColorTimestamp True
506
  ..$iif(%rcolors_ColorTimestamp != True,$style(1)) No:unset %rcolors_ColorTimestamp
507
  .-
508
  .$iif(%rcolors_nicklist,$style(1)) Enable nicklist colors:$iif(%rcolors_nicklist,unset %rcolors_nicklist,set %rcolors_nicklist True) | scid -a resetNicklist
509
  .Color nicklist style
510
  ..$iif(%rcolors_nickliststyle == $null,$style(1)) Auto:unset %rcolors_nickliststyle | rcolors_resetnicklist | scid -a resetNicklist
511
  ..$iif(%rcolors_nickliststyle == 0,$style(1)) Bright:set %rcolors_nickliststyle 0 | rcolors_resetnicklist | scid -a resetNicklist
512
  ..$iif(%rcolors_nickliststyle == 1,$style(1)) Dark:set %rcolors_nickliststyle 1 | rcolors_resetnicklist | scid -a resetNicklist
513
}