; http://dev.adiirc.com/boards/5/topics/163
; outputs same nick random color for the message
; v0.1 by pereba

on 1:START: {
  UserConf
}

on 1:LOAD: {
  UserConf
}

on 1:UNLOAD: {
  unset %RColor.*
}

alias -l UserConf {
  set %RColor.nickConfig $strip($readini(config.ini, Messages, prefixuser),c)
  set %RColor.actionConfig $strip($readini(config.ini, Messages, prefixemote),c)
  set %RColor.Enabled 1
  set %RColor.Timestamp.Enabled 1
  set %RColor.Action.Enabled 1
}

;channel
on ^*:TEXT:*:#: {
  if ($nick(#, $nick)) AND (%RColor.Enabled == 1) {
    echo $TheColor $EchoMode # $nickFormated $1-
    halt
  }
}

;action
on ^*:ACTION:*:#: {
  if (%RColor.Enabled != 1) { return }
  if ($nick(#, $nick)) AND (%RColor.Action.Enabled == 1) {
    echo $TheColor $EchoMode # $actionFormated $1-
    halt
  }
}

alias -l TheColor {
  if ($nick(#,$nick).color > 0) {
    return $nick(#,$nick).color
  }
}

alias -l EchoMode {
  if (%RColor.Timestamp.Enabled == 1) {
    return -trlmbf
  }
  return -rlmbf
}

alias actionFormated return $replacex(%RColor.actionConfig,$!pnick,$nick($chan,$nick).pnick)
alias nickFormated return $replacex(%RColor.nickConfig,$!pnick,$nick($chan,$nick).pnick)

menu menubar {
  -
  $iif(%RColor.Enabled == 1, $style(1),) 🎨 RColor Messages
  .$iif(%RColor.Enabled == 1, Disable, Enable) : $iif(%RColor.Enabled == 1, unset %RColor.Enabled, set %RColor.Enabled 1)
  .$iif(%RColor.Timestamp.Enabled == 1, $style(1),) Use timestamp : $iif(%RColor.Timestamp.Enabled == 1, unset %RColor.Timestamp.Enabled, set %RColor.Timestamp.Enabled 1)
  .$iif(%RColor.Action.Enabled == 1, $style(1),) Apply for action : $iif(%RColor.Action.Enabled == 1, unset %RColor.Action.Enabled, set %RColor.Action.Enabled 1)
  -
}