; http://dev.adiirc.com/boards/5/topics/475
; v0.2 by pereba

; Hide all idle channels and querys (no new message color):
;  /hidle

; Force unhide all windows if need:
;  /hidle un

; Lets hide inactive windows after xx seconds on AdiIRC startup?!
on *:Start: .timerhidle 0 60 hidle

; Restore windows on unloading script
on *:Unload: hidle -u

alias hidle {
  scon -a dohidle $1
}

alias dohidle {
  var %w $window(*,0), %wtype, %wname, %wid, %wcolor
  
  while (%w) {
    %wtype = $istok(channel query,$window(*,%w).type,32)
    %wname = $window(*,%w)
    %wid = $window(*,%w).wid
    %wcolor = $istok(message highlight,$window(*,%w).sbcolor,32)
    
    if ($1 == -u) && (%wtype) {
      window -w3 %wname
    }
    elseif (!%wcolor) && (%wtype && $activewid != %wid) {
      window -h %wname
    }
    
    dec %w
  }
}

; Unhide on activity
on *:Text:*:#,?: {
  var %w $iif(#,#,$nick)
  if (!$window(%w).tbstate) window -w3 %w
}

menu menubar {
  -
  Idle Windows
  .Hide no new message windows: hidle
  .Force unhidden all: hidle -n
  .-
  .Auto hide control $chr(9) $iif($timer(Hidle),On,Off):$iif($timer(hidle),.timerhidle off,.timerhidle 0 60 hidle)
}