AdiIRC

I'm sharing a simply script that makes the keyboard Scroll Look led blinks intermittently when a highlight is triggered and AdiIRC has no focus.

Demo¶

(illustrative image)

Changelog¶

• v0.5
  - Added support for action and query.
• v0.4
  - New attempt to detect user nickname ($me) correctly.
• v0.3
  - Changed to use the proper event to detect main window focus.
  - Now the led is always toggled off on focus. Thanks for the new identifier $keylocked.
  - Overall improvements.
• v0.2
  - Now using the internal identifier $highlight.
• v0.1
  - Initial release, reading user custom highlights directly from config.ini (poorly coded, not cached) :<

Script¶

; http://dev.adiirc.com/boards/5/topics/217
; Blinking scroll lock led on highlight
; v0.5 by pereba

alias -l m return * $+ $iif($$highlight($1-) == $ $+ me, $me, $v1) $+ *

alias -l led if (!$appactive) .timerLED -m 0 500 flashled

on *:TEXT:$($m($1-)):*:led

on *:ACTION:$($m($1-)):*:led

;Adi get focus then lets disable the led blinking
on *:APPACTIVE:{
  if ($timer(LED)) {
    .timerLED off
    if ($keylocked(scrolllock)) flashled
  }
}

alias flashled {
  var %name led $+ $ticks
  .comopen %name WScript.Shell
  .comclose %name $com(%name,SendKeys,3,bstr,{ScrollLock})
}

✔ mIRC compatible.