Project

General

Profile

How to change the output for some common messages/events.

Added by Per Amundsen over 1 year ago

Quit messages

on ^*:QUIT:{
  var %s 0
  while (%s < $comchan($nick, 0)) {
    inc %s
    echo -trc quit $comchan($nick, %s) * $nick ( $+ $fulladdress $+ ) has quit IRC $iif($1-,( $+ $1- $+ ),)
  }

  if ($query($nick)) {
    echo -trc quit $nick * $nick ( $+ $fulladdress $+ ) has quit IRC $iif($1-,( $+ $1- $+ ),)
  }
  halt
}

Join messages

on ^*:JOIN:*:{
  echo -trc join # * $nick ( $+ $fulladdress $+ ) joins #
  halt
}

Part messages

on ^*:PART:*:{
  echo -trc part # * $nick ( $+ $fulladdress $+ ) parts # $iif($1-,( $+ $1- $+ ),)
  halt
}

Nick messages

on ^*:NICK:{
  var %s 0
  while (%s < $comchan($nick, 0)) {
    inc %s
    echo -trc nick $comchan($nick, %s) * $nick is now known as $newnick
  }

  if ($query($nick)) {
    echo -trc nick $nick * $nick is now known as $newnick
  }
  halt
}

Topic message

on ^*:TOPIC:*:{
  echo -trc topic * $nick changes topic to $1-
  halt
}

Mode message

on ^*:MODE:*:{
  echo -trc mode * $nick sets mode $1-
  halt
}

Replies (1)

RE: How to change the output for some common messages/events. - Added by C. Syem 22 days ago

Very nice. I think is better to replace

( $+ $fulladdress $+ )

with

( $+ $remove($address($nick,1),*!*) $+ )

Because you don't need to see the nickname two times, ident and host i think is enough.

    (1-1/1)