You can edit most AdiIRC menus in the Menu Editor located at Menubar -> Tools -> Edit Menus.
Status - Edit the status menus.
Channel - Edit the channel menus.
Query - Edit the query menus.
Nicklist - Edit the nicklist menus.
Menubar - Edit the menubar menus.
ChannelLink - Edit the channel link menus. (AdiIRC only)
Link - Edit the regular link menus. (AdiIRC only)
A menu syntax consists of <Menu text><colon><Menu command>.
For this reason, only one colon is allowed in a menu, neither the text nor the command can contain any other colons for the menu to work properly.
$chr(58) can be used to add a colon in most cases.
Example
; Add a new menu item with the text "Query", when clicked, execute "/query $1" where $1 means the first word given to this menu, usually a nick. Query:/query $1
Menu commands can also contain multiple lines, if so they must be enclosed with curly brackets.
Example
; Add a new menu item with the text "Query", when clicked, execute both "/query $1" and "/whois $1".
Query:{
/query $1
/whois $1
}
See also $menu, $menutype, $menucontext, $mouse.
The "menu" prefix can also be used in a custom script to add more items to a menu, the syntax is the same.
Example
; Add a new menu item with the text "Whois", when clicked execute "/whois $1".
menu nicklist {
Whois:/whois $1
}
Multiple menus can be targeted with the same menu item by separating them with comma.
Example
; Add a new menu item for nicklist and channels with the text "Hello World", when clicked execute "/echo -ag Hello World".
menu nicklist,channel {
Hello World:/echo -ag Hello World
}
Wildcards can also be used.
Example
; Add a new menu item for all menus with the text "Hello World", when clicked execute "/echo -ag Hello World".
menu * {
Hello World:/echo -ag Hello World
}
; Add a new menu item for all custom window menus with the text "Hello World", when clicked execute "/echo -ag Hello World".
menu @* {
Hello World:/echo -ag Hello World
}
The menu hierarchy is determined by punctuation marks.
This works in both the Menu Editor and in a custom script using the Menu prefix.
Example
menu nicklist {
; Create a upper menu item called "Tools", notice you don't need a colon for the upper menu.
Tools
; Use a punctuation mark to put a sub menu item inside "Tools"
.Whois:/whois $1
; Use a punctuation mark to put another sub menu item inside "Tools"
.Who:/who $1
; Create another upper menu item called "Operate"
Operate
; Use a punctuation mark to put a sub menu item inside "Operate"
.Kill:kill $1
; Create a sub menu item called "Operate More" inside "Operate"
.Operate More
; Use two punctuation marks to put a sub menu item inside "Operate More"
..Kill again:kill $1
}
Hyphen (-) can be used to add a menu separator.
Example
menu nicklist {
; Create a upper menu item called "Tools".
Tools
; Add a separator.
-
; Create another upper menu item called "More Tools".
More Tools
; Create a submenu.
.Submenu
; Add a separator inside the submenu.
; Separators need the same amount of punctuations "." as the submenu itself.
.-
; Create another submenu.
.Submenu2
}
It's possible to merge menu items with other menu items using the same text.
Example
; Both "Apple" and "Banana" will be shown in the "Fruit" menu.
menu * {
Fruit
.Banana
}
menu * {
Fruit
.Apple
}
$1- will be filled with different words depending on the menu type.
Status - The currently connected $network name.
Channel - The current $chan name.
Query - The $nick associated with the query window.
Nicklist - A list of selected nicks in the nicklist.
Menubar - Your nick ($me) on currently connected server.
Custom Menubar Items - The name of the associated @popup menu.
As of AdiIRC 1.9.7 new top menus can be inserted in the Menubar after the "Help" item using the /menubar command.
Regular scripted menus can be used by referencing the @popup name, e.g "menu @mymenu { }"
For custom windows there are some special menu items which is triggered on various mouse events.
These menus must be at the start of the menu block.
Syntax is the same as regular menus, but the menu name must be of the following:
Picture Windows
mouse - Triggers when the mouse moves.
sclick - Triggers when the left mouse button is pressed down.
mclick - Triggers when the middle mouse button is pressed down. (AdiIRC only)
dclick - Triggers when the left mouse button is pressed down twice.
dmclick - Triggers when the middle mouse button is pressed down twice. (AdiIRC only)
drclick - Triggers when the right mouse button is pressed down twice. (AdiIRC only)
uclick - Triggers when any mouse button is released.
rclick - Triggers when the right mouse button is pressed down.
leave - Triggers when the mouse leaves the window.
drop - Triggers when the window receives a drag/drop event.
mouse.wheelup - Triggers when the mouse wheel is scrolled upwards. (AdiIRC only)
mouse.wheeldown - Triggers when the mouse wheel is scrolled downwards. (AdiIRC only)
win.resize - Triggers when the window is resized. (AdiIRC only)
win.minimize- Triggers when the window is minimized. (AdiIRC only)
win.maximize- Triggers when the window is maximized. (AdiIRC only)
win.restore- Triggers when the window is restored. (AdiIRC only)
Custom Windows text area
rclick - Triggers when the right mouse button is pressed down.
dclick - Triggers when the left mouse button is pressed down twice.
dmclick - Triggers when the middle mouse button is pressed down twice. (AdiIRC only)
drclick - Triggers when the right mouse button is pressed down twice. (AdiIRC only)
Custom Windows Nicklist
lbclick - Triggers when the left mouse button is pressed down in the listbox.
rclick - Triggers when the right mouse button is pressed down.
dclick - Triggers when the left mouse button is pressed down twice.
dmclick - Triggers when the middle mouse button is pressed down twice. (AdiIRC only)
drclick - Triggers when the right mouse button is pressed down twice. (AdiIRC only)
rclick and drclick only triggers when there is no right click menu or the right click menu has no items.
Example
; Create a custom window.
/window @test
; Add a mouse menu.
menu @test {
sclick:echo -ag Left mouse button was clicked.
rclick:echo -ag Right mouse button was clicked.
Menu:echo -ag Just a regular menu item.
}
You can style menus with check mark and disable them using the $style identifier.
Checked
menu * {
Checked $style(1):noop
}
Disabled
menu * {
Disabled $style(2):noop
}
Checked and disabled
menu * {
Checked and disabled $style(3):noop
}
In AdiIRC it's also possible to add a icon to any menu item using the $menuicon identifier.
menu * {
Icon $menuicon($scriptdir\icon.ico):noop
}
To dynamically create sub menus, the $submenu identifier can be used.
Example
menu * {
Animal
.$submenu($animal($1))
}
alias animal {
if ($1 == begin) return -
if ($1 == 1) return Dog:echo Dog
if ($1 == 2) return Cat:echo Cat
if ($1 == 3) return Bird:echo Bird
if ($1 == end) return -
}